/^srcdir.*$/,/^$/{
/^$/{
i\
VERSION=2.7
i\
tdefaults=-DSELECT_VECS=&go32coff_vec,&go32stubbedcoff_vec,&i386aout_vec\\
i\
	-DDEFAULT_VECTOR=go32coff_vec -DSELECT_ARCHITECTURES=&bfd_i386_arch
}
}
s/@tdefaults@/$(tdefaults)/
s/@wordsize@/32/
s/@HOST_64BIT_LONG@/0/
s/@HDEFINES@//
s/@TDEFINES@//
s/@COREFLAG@//
s/@COREFILE@//
s/@bfd_backends@/coff-go32.o cofflink.o aout32.o i386aout.o/
s/@bfd_machines@/cpu-i386.o/
s/@ALLLIBS@/libbfd.a/
/^stmp-bfd\.h/,/^$/{
  s!\(	.*\)\(sed -e\)!\1redir -i $(srcdir)/bfd-in2.h -o bfd.h-new \2!
  /`cat $(srcdir)\/VERSION`/{
    s/`cat $(srcdir)\/VERSION`/$(VERSION)/
    s/^\(.*-e \)"\(.*\)"\(.*$\)/\1'\2'\3/
  }
  s/[<>].*\(\\$\)/\1/
  s/[<>].*[^\\]$//
}
s/`cat ofiles`/$(OFILES)/
s/\($(TARGETLIB): .*\)ofiles.*$/\1/
/all:.*$/,/^$/{
/^	.*$/d
}
s!$(srcdir)/targets.c!$<!
